Giúp code gọi chương trình con bằng nút ấn MODE

[tan0710]

mình toàn viết =C nên k giành về ASM đâu (học lâu quên rồi )

[Ck33spkt]

ai viết dùm mây dòng đếm số lần nhấn MODE ko? mình đang học ASM.

Bạn có thể tham khảo code này:

;====================================================
; Ten chuong trinh    : Mach DK DEN bang nut bam.
; Nguoi thuc hien    : Cuong
; Ngay thuc hien    : 27/03/2012
; Phien ban    : 1.0
; Mo ta phan cung    : Dung AT89C51 - thach anh 12MHz
;        : LED giao tiep voi PORT1
;        : Cuc am cua LED noi voi GND
;       : Den 1:    P2.1 = 1 <=> Sáng
;       : Den 2:    P2.2 = 1 <=>Sáng
;       : Nut MODE:    P1.6
; Yeu cau:     An lan 1: Chuong trinh 1 hoat dong.
;         An lan 2: Chuong trinh 2 hoat dong.
;         An lan 3: Chuong trinh 3 hoat dong.
;       : Nut Stop:    P1.7
;----------------------------------------------------------------
; Ngay hoan thanh    : 27/03/2012
; Ngay kiem tra    : 27/03/2012
; Nguoi kiem tra    : Cuong
;----------------------------------------------------------------
; Chu thich    : Co the chinh sua va phat trien mo rong.
;====================================================
;
org 0000h
main:                    ;bat dau chuong trinh
    clr p2.1                ;tat 2 den
    clr p2.2
loop:    acall kt_phiman            ;goi CT kiem tra phim an
    acall ctrinh_1
    acall kt_phiman
    acall ctrinh_2
    acall kt_phiman
    acall ctrinh_3
    sjmp loop            ;thuc hien vo han vong lap
;===== CT KIEM TRA PHIM AN ======
; Ktra xem co phim nao dc an hay khong.
;-----------------------------------------------
kt_phiman:
    jnb p1.7, main            ;Co an: Stop thi tat den, ko an thi ktra phim Mode
    jb p1.6, kt_phiman            ;Ko an: Mode thi tiep tuc kiem tra phim an. Co thi ktra phim co bi giu hay ko.
    acall kt_giu            ;goi ctrinh ktra giu phim.
    ret                ;tro ve ctrinh chinh.
;---------- CT KIEM TRA GIU PHIM ---------
; Tao do tre thoi gian la 200ms de chong giu phim.
; Su dung bo dinh thoi 0 che do 1 (16bits).
;-----------------------------------------------
kt_giu:
    mov r0, #10
    mov TMOD, #01h
again:
    clr TR0
    mov TH0, #high(-20000)
    mov TL0, #low(-20000)
    setb TR0                ;Khoi dong bo dinh thoi.
wait:    jnb TF0, wait            ;Cho den khi tran.
    clr TR0
    clr TF0
    djnz r0, again            ;tre du 200ms thi thoat.
    jnb p1.6, $            ;o lai day den khi nao phim duoc nha.
    ret
;------------------------------------------------
;===========================
;---------- Che do 1 ---------------------------
ctrinh_1:
    setb p2.1
    setb p2.2
    ret
;-------------------------------------------------
;---------- Che do 2 ---------------------------
ctrinh_2:
    setb p2.1
    clr p2.2
    ret
;-------------------------------------------------
;---------- Che do 3 ---------------------------
ctrinh_3:
    clr p2.1
    setb p2.2
    ret
;-------------------------------------------------
;===========================
end                    ; Ket thuc chuong trinh chinh.

[romance_qt]

Lắp mấy nút bấm ở chân nào chẳng đc, cứ kiểm tra các chân nút bấm đó, chân nào có tác động thì gọi chương trình con của nó ra ma thực hiên.