Thông báo

Collapse
No announcement yet.

Nhờ các bác chỉ giúp cái đồng hồ này với

Collapse
X
Collapse
 
  • Trang of 3
  • Lọc
  • Giờ
  • Show
Clear All
new posts
Trước 1 2 3 template Next
  • #1

    Nhờ các bác chỉ giúp cái đồng hồ này với

    hiện nay em đang làm một đề tài về môn vi xử lý (đề tài là làm đồng hồ số hiển thị giây phút giờ ngày tháng năm) đề yêu cầu phải hiển thị ra led 7 đoạn và có thể đặt chế độ hẹn giờ.
    2 tháng trước em có làm 1 đề tài là lam đồng hồ bấm giờ thể thao,nhưng bây giờ áp dụng lai thì không được..........
    chính vì thế em mong bác có kinh nghiệm chỉ giúp em với
    em xin cảm ơn các bác nhìu nhìu lắm!!!!!
    Tags: None
  • #2
    hic sao không có ai giúp em the này,anh em giúp voiiiiiiiiiii
    đề tài cụ thể là:Đồng hồ thời gian thực:
    Truy xuất IC read-time clock dallas DS12887 hiển thị các thông số thời gian giây,phút,giờ,thứ ,ngày ,tháng ,năm ra led 7 đoạn.
    yêu cầu:
    -thiết lập được các thông số thời gian
    -thiết lập được thời gian Alarm
    Ở đây mình có mạch giờ phút giây rồi,chỉ thiếu ngày tháng năm và thứ thôi,xin các bạn chỉ giáo
    Attached Files
    Last edited by 8anhhai8; 26-06-2009, 14:18.

    Comment

    • #3
      Nguyên văn bởi 8anhhai8 Xem bài viết
      2 tháng trước em có làm 1 đề tài là lam đồng hồ bấm giờ thể thao,nhưng bây giờ áp dụng lai thì không được..........
      câu ni làm t thắc mắc nè , tại sao lúc tr làm đc mà h thì ko ? phải chăng u ko chữa đc chương trình do chính tay mình viết ????

      Mún ae giúp thì ít nhất u post cái code + mạch lên , đặng biết sai ở đâu mà chữa chứ , ok ?

      Comment

      • #4
        thanks Bi da hoi am cho minh.
        gio minh goi code cho BI, minh nho BI chinh giup nhe.
        day la code cua minh :
        ;CHUONG TRINH CHAY GIO PHUT GIAY NGAY THANG NAM
        K BIT P3.4
        K1 BIT P3.5
        K2 BIT P3.6
        K3 BIT P3.7

        GIO EQU 12H
        PHUT EQU 13H
        GIAY EQU 14H
        NGAY EQU 15H
        THANG EQU 16H
        NAM EQU 17H
        ORG 0000H
        LJMP MAIN
        ORG 000BH
        LJMP NGATT0
        MAIN:
        MOV SP,#5FH
        MOV TMOD,#11H
        CLR TF0
        MOV TL0,#LOW(-10000)
        MOV TH0,#HIGH(-10000)
        SETB TR0
        MOV DPTR,#LED
        MOV R2,#00
        MOV GIO,#00H
        MOV PHUT,#00H
        MOV GIAY,#00H

        MOV NGAY,#01
        MOV THANG,#01
        MOV NAM,#05

        MOV 30H,#01
        MOV 31H,#00
        MOV 32H,#00
        MOV 33H,#02
        MOV 34H,#00
        MOV 35H,#00
        MOV 36H,#00
        MOV 11H,#07
        MOV IE,#82H ;CHO PHEP NGAT TIMER0

        LAP: LCALL HIEN_THI

        CJNE R2,#100,LAP
        MOV R2,#00
        INC GIAY
        MOV A,GIAY
        CJNE A,#06,LAP
        MOV GIAY,#00
        INC PHUT
        MOV A,PHUT
        CJNE A,#02,LAP
        MOV PHUT,#00
        INC GIO
        MOV A,GIO
        CJNE A,#01,LAP
        MOV GIO,#00

        MOV A,NGAY
        CJNE A,#01,A2
        MOV A,THANG
        CJNE A,#01,A1
        MOV NGAY,#31
        MOV THANG,#12
        MOV A,NAM
        CJNE A,#0,A9
        MOV NAM,#99
        JMP OUT3
        A9: DEC NAM
        JMP OUT3
        A1: CJNE A,#03,A3
        MOV A,NAM
        MOV B,#04
        DIV AB
        MOV A,B
        CJNE A,#00,A6
        MOV NGAY,#29
        DEC THANG
        JMP OUT3
        A6: MOV NGAY,#28
        DEC THANG
        JMP OUT3
        A3: CJNE A,#05,A4
        LUI: MOV NGAY,#30
        DEC THANG
        JMP OUT3
        A4: CJNE A,#07,A5
        JMP LUI
        A5: CJNE A,#10,A7
        JMP LUI
        A7: CJNE A,#12,A8
        JMP LUI
        A2: DEC NGAY
        JMP OUT3
        A8: MOV NGAY,#31
        DEC THANG
        OUT3: JMP LAP

        HIEN_THI:
        MOV R1,#11000000B
        MOV R0,#11H
        L00P1: LCALL QUETLED
        JB K,MODE1 ; QUET PHIM K
        INC R0
        INC R1
        CJNE R0,#18H,L00P1
        RET
        NGATT0:

        CLR TF0
        CLR TR0
        INC R2
        MOV TL0,#LOW(-10000)
        MOV TH0,#HIGH(-10000)
        SETB TR0
        RETI
        MODE1: ;CHINH GIO
        JB K,MODE1
        MOV R1,#11000010B
        MOV R0,#12H
        LAP1: LCALL QUETLED
        JB K,MODE2
        JB K1, KEY1
        JB K2, KEY2
        INC R1
        INC R0
        CJNE R0,#15H,LAP1
        MOV R0,#12H
        MOV R1,#11000010B
        JMP LAP1

        KEY1: JB K1,KEY1
        INC GIO
        MOV A,GIO
        CJNE A,#24,L1
        MOV GIO,#00
        L1:
        LCALL HIEN_THI
        JMP LAP1

        KEY2:
        JB K2,KEY2
        INC PHUT
        MOV A,PHUT
        CJNE A,#60,L2
        MOV PHUT,#00
        L2: LCALL HIEN_THI
        JMP LAP1
        MODE2: ;CHINH LICH
        JB K,MODE2
        MOV R1,#11001000B
        MOV R0,#15H
        LAP2: LCALL QUETLED
        JB K,THOAT ;NHAY DEN MODE3 CHINH BO HEN GIO 1
        JB K1,KEY3
        JB K2,KEY4
        JB K3,KEY5
        INC R1
        INC R0
        CJNE R0,#18H,LAP2
        MOV R0,#15H
        MOV R1,#11001000B
        JMP LAP2

        KEY3:
        JB K1,KEY3
        INC NGAY
        MOV A,NGAY
        CJNE A,#32,L3
        MOV NGAY,#01
        L3:
        LCALL HIEN_THI
        JMP LAP2
        KEY4:
        JB K2,KEY4
        INC THANG
        MOV A,THANG
        CJNE A,#13,L4
        MOV THANG,#01
        L4:
        LCALL HIEN_THI
        JMP LAP2
        KEY5:
        JB K3,KEY5
        INC NAM
        MOV A,NAM
        CJNE A,#100,L5
        MOV NAM,#00
        L5:
        LCALL HIEN_THI
        JMP LAP2
        THOAT:
        JB K,THOAT
        MOV IE,#82H ;CHO PHEP NGAT TIMER 0
        CLR TF0
        SETB TR0
        JMP LAP
        QUETLED:
        MOV A,@R0
        MOV B,#0AH
        DIV AB
        MOVC A,@A+DPTR
        MOV P0,A
        MOV A,R1
        MOV P2,A
        MOV R7,#10H
        DJNZ R7,$
        MOV P2,#0FFH
        MOV A,B
        MOVC A,@A+DPTR
        MOV P0,A
        INC R1
        MOV A,R1
        MOV P2,A
        MOV R7,#10H
        DJNZ R7,$
        MOV P2,#0FFH
        RET

        LED:
        DB 0C0H,0F9H,0A4H,0B0H,099H,092H,082H,0F8H,080H,090H
        END
        mong hoi am cua BI(BI co mail ko cho minh xin duoc ko co gi minh de lien lac) thanks!!!!

        Comment

        • #5
          Nguyên văn bởi 8anhhai8 Xem bài viết
          thanks Bi da hoi am cho minh.
          gio minh goi code cho BI, minh nho BI chinh giup nhe.
          day la code cua minh :
          ;CHUONG TRINH CHAY GIO PHUT GIAY NGAY THANG NAM
          K BIT P3.4
          K1 BIT P3.5
          K2 BIT P3.6
          K3 BIT P3.7

          GIO EQU 12H
          PHUT EQU 13H
          GIAY EQU 14H
          NGAY EQU 15H
          THANG EQU 16H
          NAM EQU 17H
          ORG 0000H
          LJMP MAIN
          ORG 000BH
          LJMP NGATT0
          MAIN:
          MOV SP,#5FH
          MOV TMOD,#11H
          CLR TF0
          MOV TL0,#LOW(-10000)
          MOV TH0,#HIGH(-10000)
          SETB TR0
          MOV DPTR,#LED
          MOV R2,#00
          MOV GIO,#00H
          MOV PHUT,#00H
          MOV GIAY,#00H

          MOV NGAY,#01
          MOV THANG,#01
          MOV NAM,#05

          MOV 30H,#01
          MOV 31H,#00
          MOV 32H,#00
          MOV 33H,#02
          MOV 34H,#00
          MOV 35H,#00
          MOV 36H,#00
          MOV 11H,#07
          MOV IE,#82H ;CHO PHEP NGAT TIMER0

          LAP: LCALL HIEN_THI

          CJNE R2,#100,LAP
          MOV R2,#00
          INC GIAY
          MOV A,GIAY
          CJNE A,#06,LAP
          MOV GIAY,#00
          INC PHUT
          MOV A,PHUT
          CJNE A,#02,LAP
          MOV PHUT,#00
          INC GIO
          MOV A,GIO
          CJNE A,#01,LAP
          MOV GIO,#00

          MOV A,NGAY
          CJNE A,#01,A2
          MOV A,THANG
          CJNE A,#01,A1
          MOV NGAY,#31
          MOV THANG,#12
          MOV A,NAM
          CJNE A,#0,A9
          MOV NAM,#99
          JMP OUT3
          A9: DEC NAM
          JMP OUT3
          A1: CJNE A,#03,A3
          MOV A,NAM
          MOV B,#04
          DIV AB
          MOV A,B
          CJNE A,#00,A6
          MOV NGAY,#29
          DEC THANG
          JMP OUT3
          A6: MOV NGAY,#28
          DEC THANG
          JMP OUT3
          A3: CJNE A,#05,A4
          LUI: MOV NGAY,#30
          DEC THANG
          JMP OUT3
          A4: CJNE A,#07,A5
          JMP LUI
          A5: CJNE A,#10,A7
          JMP LUI
          A7: CJNE A,#12,A8
          JMP LUI
          A2: DEC NGAY
          JMP OUT3
          A8: MOV NGAY,#31
          DEC THANG
          OUT3: JMP LAP

          HIEN_THI:
          MOV R1,#11000000B
          MOV R0,#11H
          L00P1: LCALL QUETLED
          JB K,MODE1 ; QUET PHIM K
          INC R0
          INC R1
          CJNE R0,#18H,L00P1
          RET
          NGATT0:

          CLR TF0
          CLR TR0
          INC R2
          MOV TL0,#LOW(-10000)
          MOV TH0,#HIGH(-10000)
          SETB TR0
          RETI
          MODE1: ;CHINH GIO
          JB K,MODE1
          MOV R1,#11000010B
          MOV R0,#12H
          LAP1: LCALL QUETLED
          JB K,MODE2
          JB K1, KEY1
          JB K2, KEY2
          INC R1
          INC R0
          CJNE R0,#15H,LAP1
          MOV R0,#12H
          MOV R1,#11000010B
          JMP LAP1

          KEY1: JB K1,KEY1
          INC GIO
          MOV A,GIO
          CJNE A,#24,L1
          MOV GIO,#00
          L1:
          LCALL HIEN_THI
          JMP LAP1

          KEY2:
          JB K2,KEY2
          INC PHUT
          MOV A,PHUT
          CJNE A,#60,L2
          MOV PHUT,#00
          L2: LCALL HIEN_THI
          JMP LAP1
          MODE2: ;CHINH LICH
          JB K,MODE2
          MOV R1,#11001000B
          MOV R0,#15H
          LAP2: LCALL QUETLED
          JB K,THOAT ;NHAY DEN MODE3 CHINH BO HEN GIO 1
          JB K1,KEY3
          JB K2,KEY4
          JB K3,KEY5
          INC R1
          INC R0
          CJNE R0,#18H,LAP2
          MOV R0,#15H
          MOV R1,#11001000B
          JMP LAP2

          KEY3:
          JB K1,KEY3
          INC NGAY
          MOV A,NGAY
          CJNE A,#32,L3
          MOV NGAY,#01
          L3:
          LCALL HIEN_THI
          JMP LAP2
          KEY4:
          JB K2,KEY4
          INC THANG
          MOV A,THANG
          CJNE A,#13,L4
          MOV THANG,#01
          L4:
          LCALL HIEN_THI
          JMP LAP2
          KEY5:
          JB K3,KEY5
          INC NAM
          MOV A,NAM
          CJNE A,#100,L5
          MOV NAM,#00
          L5:
          LCALL HIEN_THI
          JMP LAP2
          THOAT:
          JB K,THOAT
          MOV IE,#82H ;CHO PHEP NGAT TIMER 0
          CLR TF0
          SETB TR0
          JMP LAP
          QUETLED:
          MOV A,@R0
          MOV B,#0AH
          DIV AB
          MOVC A,@A+DPTR
          MOV P0,A
          MOV A,R1
          MOV P2,A
          MOV R7,#10H
          DJNZ R7,$
          MOV P2,#0FFH
          MOV A,B
          MOVC A,@A+DPTR
          MOV P0,A
          INC R1
          MOV A,R1
          MOV P2,A
          MOV R7,#10H
          DJNZ R7,$
          MOV P2,#0FFH
          RET

          LED:
          DB 0C0H,0F9H,0A4H,0B0H,099H,092H,082H,0F8H,080H,090H
          END
          mong hoi am cua BI(BI co mail ko cho minh xin duoc ko co gi minh de lien lac) thanks!!!!
          Code asm ah
          khó kiểm tra nhỉ
          sao bạn không chuyển sang C viết code cho dễ?
          Khi đó bạn sẽ chuyển từ code trước sang một cách dễ dàng

          Comment

          • #6
            uhm, viết code asm thì ct của ai người đó hiểu thôi, chứ nhờ người khác sửa dùm rất là khó. Nói vậy chứ mình cũng chỉ biết viết bằng asm thôi!

            Comment

            • #7
              cam on vodang va kkk da hoi am
              minh chi bit viet bang ám thoi , neu co cho nao sai thi nho 2 ban chi giup,chu gio minh roi wa roi .thanks 2 ban nhiu ,neu co the thi cho minh xin mail 2 ban dc ko co gi de lien lac.2 ban giup minh voi nhe
              !!!!!!!!!

              Comment

              • #8
                cac bac oi, cac bac dau roi tra loi em di chu.
                em xin noi ro cai de tai cua em lan nua cho cac bac huong dan giup em:
                dong ho thoi gian thuc:
                Truy xuat IC read-time clock dallasDS12887 hien thi cac thong so thoi gian

                Comment

                • #9
                  Ko phải mọi ng ko giúp , tưởng u viết C , nhìn ASM thì mù . Xem có bác nào viết ASM , bác í chữa giúp cho . post lun cái hình nguyên lí lên cho bác í lun . thế nhé

                  Comment

                  • #10
                    Đây! code đồng hồ giao tiếp 8051 với DS12887
                    Hiển thị ngày tháng năm giờ phút giây, có hiệu chỉnh thời gian và đặt giờ báo chuông
                    Code:
                    ;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
; p2 dieu khien 8 led va p3.0, p3.1, p3.2, p3.4, p3.5
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

dwn		bit 	p3.3
up		bit	p3.1
mode		bit	p3.0
mode1		bit	p3.5
bell		bit	p3.4


;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
		org	000h
		jmp	main

		org	003h
		jmp	ngat_n0
	
main:		mov	r3,#0
		lcall	khoitaodallass
		lcall	delay
		mov	ie,#81h
		setb	it0
tu_dau1:	setb	bell
		mov	r2,#0

tu_dau:		lcall	doc_data	
		lcall	hex_bcd
		lcall	bcd_7doan
		lcall	hien_thi
		jb	mode,adj
		jb	mode1,adj_alr
		cjne	r2,#0,ngat_bell
		sjmp	tu_dau

ngat_bell:	lcall	doc_data
		mov	a,4fh
		add	a,#2
		cjne	a,#60,kt_c23
kt_c23:		jc	tiep
		mov	4fh,10h
		jmp	tu_dau

tiep:		cjne	a,10h,tu_dau

		mov	4fh,10h
		cpl	bell
		djnz	4eh,tu_dau
		mov	r0,#0ch
		movx	a,@r0
		jmp	tu_dau1

adj_alr:		jmp	set_alr
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

adj:		lcall	hien_thi
		jb	mode,adj

		mov	78h,#15
adj1:		lcall	hien_thi
		jb	mode,adj
		djnz	78h,adj1

		inc	r3
		cjne	r3,#08,loop	
		mov	r3,#0
		ljmp	tu_dau
			
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
loop:		mov	67h,#10

loop3:		mov	66h,#0afh
loop1:		lcall	doc_data
		lcall	hex_bcd
		lcall	bcd_7doan
		lcall	hien_thi

		jb	up,tang
		jb	dwn,giam1
		jb	mode,adj
		djnz	66h,loop1

		cjne	r3,#1,tatphut
		mov	34h,#0ffh
		mov	35h,#0ffh
		sjmp	tat

tatphut:		cjne	r3,#02,tatgio
		mov	32h,#0ffh
		mov	33h,#0ffh
		sjmp	tat

tatgio:		cjne	r3,#03,tatthu
		mov	30h,#0ffh
		mov	31h,#0ffh
		sjmp	tat

tatthu:		cjne	r3,#04,tatngay
		mov	36h,#0ffh
		sjmp	tat

tatngay:		cjne	r3,#05,tatthang
		mov	37h,#0ffh
		mov	38h,#0ffh
		sjmp	tat

tatthang:	cjne	r3,#06,tatnam
		mov	39h,#0ffh
		mov	3ah,#0ffh
		sjmp	tat

tatnam:		mov	3eh,#0ffh
		mov	3dh,#0ffh

tat:		mov	66h,#0afh
loop2:		lcall	hien_thi

		jb	up,tang
		jb	dwn,giam1
		jb	mode,adj2
		djnz	66h,loop2
		djnz	67h,loop3
		mov	r3,#0
		ljmp	tu_dau

adj2:		ljmp	adj

;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
giam1:		ljmp	giam
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

tang:		mov	78h,#100
tang1:		lcall	hien_thi
		djnz	78h,tang1

		cjne	r3,#01h,ss1		
		mov	r0,#04h			
		movx	a,@r0
		inc	a
		cjne	a,#24,z1
		mov	a,#0
z1:		movx	@r0,a
		jmp	loop	
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

ss1:		cjne	r3,#02h,ss2	
		mov	r0,#02h
		movx	a,@r0
		inc	a
		cjne	a,#60,z1
		mov	a,#0
		jmp	z1
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

ss2:		cjne	r3,#03,ss3
		mov	r0,#0h
		movx	a,@r0
		inc	a
		cjne	a,#060,z1
		mov	a,#0
		jmp	z1
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

ss3:		cjne	r3,#04,ss4
		mov	r0,#06h
		movx	a,@r0
		inc	a
		cjne	a,#08,z1
		mov	a,#01
		jmp	z1
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

ss4:		cjne	r3,#05,ss5
		mov	r0,#07h
		movx	a,@r0
		inc	a
		cjne	a,#032,z1
		mov	a,#00
		jmp	z1
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

ss5:		cjne	r3,#06,ss6
		mov	r0,#08h
		movx	a,@r0
		inc	a
		cjne	a,#013,z1
		mov	a,#01
		jmp	z1
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
ss6:		mov	r0,#09h
		movx	a,@r0
		inc	a
		cjne	a,#100,z1
		mov	a,#00
		jmp	z1

;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

giam:		mov	78h,#100
giam11:		lcall	hien_thi
		djnz	78h,giam11
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

		cjne	r3,#01h,sss1		
		mov	r0,#04			
		movx	a,@r0
		dec	a
		cjne	a,#0ffh,zz1
		mov	a,#23
zz1:		movx	@r0,a
		jmp	loop
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

sss1:		cjne	r3,#02h,sss2	
		mov	r0,#02h
		movx	a,@r0
		dec	a
		cjne	a,#0ffh,zz1
		mov	a,#59
		jmp	zz1
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

sss2:		cjne	r3,#03h,sss3	
		mov	r0,#0h
		movx	a,@r0
		dec	a
		cjne	a,#0ffh,zz1
		mov	a,#59
		jmp	zz1
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
	
sss3:		cjne	r3,#04h,sss4
		mov	r0,#06h
		movx	a,@r0
		dec	a
		cjne	a,#0h,zz1
		mov	a,#7
		jmp	zz1
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

sss4:		cjne	r3,#05h,sss5
		mov	r0,#07h
		movx	a,@r0
		dec	a
		cjne	a,#0ffh,zz1
		mov	a,#31
		jmp	zz1
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

sss5:		cjne	r3,#06,sss6
		mov	r0,#08h
		movx	a,@r0
		dec	a
		cjne	a,#01h,zz1
		mov	a,#12
		jmp	zz1
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

sss6:		mov	r0,#09
		movx	a,@r0
		dec	a
		cjne	a,#0ffh,zz1
		mov	a,#99
		jmp	zz1

;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
; doan ct cai dat bao thuc

set_alr:		lcall	hien_thi_alr
		jb	mode1,set_alr

set_a:		inc	r3
		cjne	r3,#4,wait
		mov	r3,#0
		ljmp	tu_dau

wait:		mov	67h,#10
wait3:		mov	66h,#0ffh
		lcall	doc_data_alr
		lcall	hex_bcd
		lcall	bcd_7doan
wait1:		lcall	hien_thi_alr

		jb	up,tang_alr
		jb	dwn,giam_alr
		jb	mode1,set_alr
		djnz	66h,wait1

		cjne	r3,#1,tatphut_alr
		mov	35h,#0ffh
		mov	34h,#0ffh
		sjmp	tat_alr

tatphut_alr:	cjne	r3,#2,tatgiay_alr
		mov	32h,#0ffh
		mov	33h,#0ffh
		sjmp	tat_alr

tatgiay_alr:	mov	31h,#0ffh
		mov	30h,#0ffh

tat_alr:		mov	66h,#0ffh
wait2:		lcall	hien_thi_alr

		jb	up,tang_alr
		jb	dwn,giam_alr
		jb	mode1,set_alr
		djnz	66h,wait2
		djnz	67h,wait3
		mov	r3,#0
		ljmp	tu_dau

;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

tang_alr:	mov	78h,#200
tang1_alr:	lcall	hien_thi_alr
		djnz	78h,tang1_alr

waitx3:	cjne	r3,#01h,ss_alr1		
		mov	r0,#05h			
		movx	a,@r0
		inc	a
		cjne	a,#24,z_alr1
		mov	a,#0
z_alr1:		movx	@r0,a
		jmp	wait	
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

ss_alr1:		cjne	r3,#2,ss_alr2
		mov	r0,#03h
		movx	a,@r0
		inc	a
		cjne	a,#60,z_alr1
		mov	a,#0
		jmp	z_alr1

ss_alr2:		mov	r0,#01h
		movx	a,@r0
		inc	a
		cjne	a,#60,z_alr1
		mov	a,#0
		jmp	z_alr1

;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

giam_alr:	mov	78h,#200
giam_alr11:	lcall	hien_thi_alr
		djnz	78h,giam_alr11
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

waity3:	cjne	r3,#01h,sss_alr1		
		mov	r0,#5			
		movx	a,@r0
		dec	a
		cjne	a,#0ffh,zz_alr1
		mov	a,#24
zz_alr1:		movx	@r0,a
		jmp	wait	
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

sss_alr1:	cjne	r3,#2,sss_alr2
		mov	r0,#03h
		movx	a,@r0
		dec	a
		cjne	a,#0ffh,zz_alr1
		mov	a,#59
		jmp	zz_alr1

sss_alr2:	mov	r0,#01h
		movx	a,@r0
		dec	a
		cjne	a,#0ffh,zz_alr1
		mov	a,#59
		jmp	zz_alr1
		
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
khoitaodallass:	mov	r0,#0bh
		mov	a,#026h
		movx	@r0,a	;cho phep chinh cai dat gio

		mov	r0,#0ah
		mov	a,#020h
		movx	@r0,a	;cho phep bo dao dong chay 

		mov	r0,#0ch
		movx	a,@r0
		ret
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
doc_data:	mov	r0,#0
		mov	r1,#10h

	x1:	movx	a,@r0
		mov	@r1,a

		inc	r0
		inc	r0
		inc	r1
		cjne	r0,#06h,x1	 

		movx	a,@r0
		mov	@r1,a

		inc	r1
		inc	r0
	
x2:		movx	a,@r0
		mov	@r1,a
		inc	r0
		inc	r1
		cjne	r0,#0ah,x2
		ret
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
doc_data_alr:	mov	r0,#01h
		movx	a,@r0
		mov	10h,a

		mov	r0,#03h
		movx	a,@r0
		mov	11h,a

		mov	r0,#05h
		movx	a,@r0
		mov	12h,a
		ret

;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
hex_bcd:	mov	r0,#10h
		mov	r1,#20h

hb:		mov	a,@r0
		mov	b,#10
		div	ab
		mov	@r1,b
		inc	r1
		mov	@r1,a

		inc	r0
		inc	r1
		cjne	r0,#13h,hb

		mov	26h,13h		; thu

		mov	r0,#014h
		mov	r1,#27h

hb1:		mov	a,@r0
		mov	b,#10
		div	ab
		mov	@r1,a
		inc	r1
		mov	@r1,b

		inc	r0
		inc	r1
		cjne	r0,#17h,hb1
		ret

;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

bcd_7doan:	mov	dptr,#900h
		mov	r0,#20h
		mov	r1,#30h ;chua cac ma data
		
x3:		mov	a,@r0 	;lay giay
		movc	a,@a+dptr
		mov	@r1,a

		inc	r0
		inc	r1
		cjne	r0,#2dh,x3
		
		mov	3dh,3bh
		mov	3eh,3ch

		mov	3bh,#0a4h
		mov	3ch,#0c0h

		mov	a,36h
		cjne	a,#0f9h,exit3
		mov	36h,#0c6h
		
exit3:		ret

;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
hien_thi:	mov	r0,#30h
		mov	a,#0feh

ht:		mov	p0,@r0
		mov	p1,a
		lcall	delay
		mov	p1,#0ffh

		inc	r0
		rl	a
		cjne	a,#0feh,ht
	
ht1:		mov	p0,@r0
		mov	p2,a
		lcall	delay
		mov	p2,#0ffh
		inc	r0
		rl	a
		cjne	a,#07fh,ht1
		ret
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

hien_thi_alr:	mov	r0,#30h
		mov	a,#0feh

ht11:		mov	p0,@r0
		mov	p1,a
		lcall	delay
		mov	p1,#0ffh

		inc	r0
		rl	a
		cjne	a,#0bfh,ht11
		ret
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
ngat_n0:	mov	4fh,10h
		mov	4eh,#6
		mov	r2,#1
		clr	bell
		reti

;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

delay:		mov	7fh,#100
		djnz	7fh,$
		ret

;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx	
	org	900h

db	0c0h,0f9h,0a4h,0b0h,99h,92h,82h,0f8h,80h,90h
	end
                    Trần Đức Sơn

                    tel:0934691385

                    Comment

                    • #11
                      da em cam on anh cddt061 nhieu.
                      em se thu chay no,co cho nao em khong hieu mong anh giai thich giup em .
                      thanks anh nhiu.

                      Comment

                      • #12
                        phần lập trình cddt061 chính xác ko vậy? cddt061 đã làm mô hình và chạy thử chưa? sao ko post cụ thể mạch nguyên lý cho anh em tham khảo.Chứ nhiều người sai nhưng cứ post lên làm anh em ko biết đâu mà lần. lập trình thì mỗi người một kiểu. có sơ đồ cho nó dễ hình dung. Nếu được thì cảm ơn nhé
                        Last edited by Doan_Huynh; 01-07-2009, 13:07.

                        Comment

                        • #13
                          Đây là mạch và code mình đã làm và chạy OK. Bạn Doan Huynh có gửi mail hỏi mình tài liệu về phần hẹn giờ, nhưng mình chỉ đọc trong Datasheet rồi làm theo chứ không có tài liệu. Mà mình thấy phần báo thức là do ngắt trong RTC tự sinh ra chứ đâu có gì. Mình là dân IT nên cũng không biết nhiều nên chỉ có thể chia sẻ với bạn thế.
                          Attached Files

                          Comment

                          • #14
                            Thanks. Cảm ơn vì đã chia sẻ. mà dùng Eagle đẻ mở ah. nếu có mạch nguyên lý thì share cho mình luôn... mạch in nhìn ko quen.
                            Last edited by Doan_Huynh; 01-07-2009, 23:31.

                            Comment

                            • #15
                              co bac nao co file proteut thi cho em lun duoc khong.em cam on nhiu

                              Comment

                              Trước 1 2 3 template Next

                              Về tác giả

                              Collapse
                              8anhhai8 Tìm hiểu thêm về 8anhhai8

                              Bài viết mới nhất

                              Collapse
                              Xem toàn bộ
                              Đang tải...
                              X