Thông báo

Collapse
No announcement yet.

Bác nào giúp em code ASM

Collapse
X
Collapse
 
  • Trang of 1
  • Lọc
  • Giờ
  • Show
Clear All
new posts
Trước template Next
  • #1

    Bác nào giúp em code ASM

    Bác nào giúp hộ em fix cái code em làm đèn giao thông
    Khi ấn cái nút nhấn để chuyển chế độ ban đêm <=> ban ngày đến lần thứ 3 thì ko hiều sao led 7 đoạn tắt hết trơn ( 2 lần ấn trước vẫn hoạt động bình thường )
    Em up lên mong mọi người tìm dc lỗi giúp em ( Mới lập trình cái này đầu tiên nên code hơi dở tí mong mọi người thông cảm )

    http://www.mediafire.com/?1oma0pn0p8p06b9
    Tags: None
  • #2
    Nguyên văn bởi vippro1610 Xem bài viết
    Bác nào giúp hộ em fix cái code em làm đèn giao thông
    Khi ấn cái nút nhấn để chuyển chế độ ban đêm <=> ban ngày đến lần thứ 3 thì ko hiều sao led 7 đoạn tắt hết trơn ( 2 lần ấn trước vẫn hoạt động bình thường )
    Em up lên mong mọi người tìm dc lỗi giúp em ( Mới lập trình cái này đầu tiên nên code hơi dở tí mong mọi người thông cảm )

    http://www.mediafire.com/?1oma0pn0p8p06b9
    Mình thấy code của bạn không dung timer để quet led mình đoán chắc bạn dùng mạch chốt địa chỉ
    Còn code mình thấy bạn dùng 2 NHÃN kiểm tra theo mình không phải dùng 2 NHÃN như vậy chỉ cần cho lệnh kiểm tra trước các chương trình chạy của từng chế độ
    Bạn có thể tham khảo mạch NÀY

    Bạn có thể cho sơ đồ nguyên lý lên được không
    Bạn chụp hình lại cho lên tốt hơn (vì mình Proteus phiển bản thấp)

    Comment

    • #3
      Nguyên văn bởi vippro1610 Xem bài viết
      Bác nào giúp hộ em fix cái code em làm đèn giao thông
      Khi ấn cái nút nhấn để chuyển chế độ ban đêm <=> ban ngày đến lần thứ 3 thì ko hiều sao led 7 đoạn tắt hết trơn ( 2 lần ấn trước vẫn hoạt động bình thường )
      Em up lên mong mọi người tìm dc lỗi giúp em ( Mới lập trình cái này đầu tiên nên code hơi dở tí mong mọi người thông cảm )

      http://www.mediafire.com/?1oma0pn0p8p06b9
      một gợi ý cho bạn:khi bạn chuyển chế độ ngày và đêm phải đảm bảo rằng tất cả các ct con phải được thoát ra.
      bạn tự sửa code theo gợi ý nếu không được tôi sẽ đưa code lên.
      bạn mô phỏng thử file tôi gởi kèm.
      Attached Files
      |

      Comment

      • #4
        @ haprohaui : Hix ko có code thi em sao tham khảo dc . Em xài 2 lần kiểm tra , lần 1 kiểm tra để chuyển từ ban ngày -> ban đêm , lần 2 thì từ ban đêm về lại ban ngày , em chỉ sử dụng 1 nút nhấn. Cái timer với counter hồi đó học lơ mơ quá nên ko dám xài . Em chỉ xài delay bình thường



        @tdm : Em vẫn ko biết chưa thoát CT con nào nữa . Cái mô phỏng của anh sao đèn xanh đỏ ko đèn nào sáng hết vậy

        ( Code này em edit lại cho nó gọn chứ vẫn giống như code em up ở trên )

        tg_xanh equ 50h
        tg_do equ 51h
        do equ 40
        xanh equ 35

        org 00h

        main:
        mov tg_xanh,#xanh
        mov tg_do,#do
        tudau:
        mov p1,#11110011b
        mov R0,tg_xanh
        mov R1,tg_do
        lap1: dec r0
        dec r1
        call hex_bcd
        call giaima
        call hienthi
        cjne r0,#0,lap1
        mov p1,#11110101b
        mov r0,#5
        lap2: dec r0
        dec r1
        call hex_bcd
        call giaima
        call hienthi
        cjne r0,#0,lap2
        mov p1,#11011110b
        mov r0,tg_do
        mov r1,tg_xanh
        lap3: dec r0
        dec r1
        call hex_bcd
        call giaima
        call hienthi
        cjne r1,#0,lap1
        mov p1,#11101110b
        mov r1,#5
        lap4: dec r0
        dec r1
        call hex_bcd
        call giaima
        call hienthi
        cjne r1,#0,lap4
        jmp tudau
        bandem:
        mov p1,#11101101b
        call delay500ms
        mov p1,#11111111b
        call delay500ms
        jmp bandem

        hex_bcd:
        mov A,R0
        mov B,#10
        div AB
        mov 37h,B
        mov 36h,A

        mov A,R1
        mov B,#10
        div AB
        mov 31h,B
        mov 30h,A
        Ret

        giaima:
        mov DPTR,#0500h
        mov A,37h
        movc A,@A+DPTR
        mov 27h,A
        mov A,36h
        movc A,@A+DPTR
        mov 26h,A
        mov A,31h
        movc A,@A+DPTR
        mov 21h,A
        mov A,30h
        movc A,@A+DPTR
        mov 20h,A
        Ret

        hienthi:
        mov R5,#150
        lap5:
        setb p2.0
        mov p0,26h
        call delay1ms
        clR p2.0
        setb p2.1
        mov p0,27h
        call delay1ms
        clR p2.1
        setb p2.2
        mov p0,20h
        call delay1ms
        clR p2.2
        setb p2.3
        mov p0,21h
        call delay1ms
        clR p2.3
        call kiemtra
        djnz R5,lap5
        ret

        kiemtra:
        jb p2.4,thoat ; kiem tra nut nhan de chuyen qua che do ban dem
        jnb p2.4,$ ; kiem tra nut nhan da dc nha
        jmp bandem
        thoat: ret

        delay1ms:
        mov 71h,#2
        D3: mov 72h,#255
        DJNZ 72h,$
        DJNZ 71h,D3
        Ret



        delay500ms:
        mov 73h,#2
        D6: mov 74h,#255
        D7: call kiemtra2
        mov 75h,#255
        DJNZ 75h,$
        DJNZ 74h,D7
        DJNZ 73h,D6
        Ret

        kiemtra2:
        jb p2.4,thoat1 ; kiem tra nut nhan de tro ve che do binh thuong
        jnb p2.4,$ ; kiem tra nut nhan da duoc nha
        jmp tudau
        thoat1: Ret

        org 0500h
        ma7d:
        DB 0c0h,0f9h,0a4h,0b0h,99h,92h,82h,0f8h,80h,90h

        end

        Comment

        • #5
          Code đây bạn ơi
          Code:
          	;///////////////////////////////////////////////////////
	;//***************************************************//
	;//**	MẠCH ĐÈN GIAO THÔNG SỬ DỤNG 89C52 	    **//
	;//**	BY: HAPROHAUI				    **//       
	;//**	YAHOO: ha_k4a				    **//
	;//**	EMAIL: haprohaui@gmail.com		    **//
	;//***************************************************//
	;///////////////////////////////////////////////////////
	ORG 	0000H
	LJMP	INIT
	ORG	0003H	;KHONG CHO CAC NGAT NGOAI LAM VIEC
	RETI
	ORG	000BH	;
	RETI
	ORG	0013H	;
	RETI
	ORG	0023H	;
	RETI
	ORG	002BH	;CHO TIME2 LAM VIEC
	LJMP	INT_T2
;=============================
;KHAI BAO BIEN
;=============================
	NUM	EQU	50H
	D0	EQU	51H
	D1	EQU	52H
	TIC	EQU	53H
	SEC	EQU	54H
	PRUN	EQU	P1.0
	PNN	EQU	P1.1
	PSTOP	EQU	P1.2
	MODE1F	EQU	00H
	MODE2F	EQU	01H
	RUNF	EQU	02H
	NNF	EQU	03H
	STOP	EQU	04H
;=============================
;KET THUC KHAI BAO BIEN
;=============================
	;************************************************
	;	NGAN CACH GIUA CAC CHUONG TRINH
	;************************************************
;=============================
;	KHOI TAO CHUONG TRINH
;=============================
	ORG	100
INIT:
	CLR	EA		;XOA THANH GHI EA
	MOV	SP,#2FH		;KHOI TAO NGAN XEP
	MOV	T2CON,#04H	;DE LAM VIEC CHE DO T2
				;VA AUTO_RLLOAD
	MOV	RCAP2H,#0B1H	;CHU KY LAM VIEC 20mS
	MOV	RCAP2L,#0E0H	;CHU KY LAM VIEC 20mS
	MOV	NUM,#50
	MOV	TIC,#0
	MOV	SEC,#0
	MOV	MODE1F,#0
	MOV	MODE2F,#0
	MOV	RUNF,#1
	MOV	P3,#0
	MOV	R7,#0
	SETB	IE.5
	SETB	EA
HERE:
	SJMP	HERE
;===============================
;	KET THUC CHUONG TRINH
;===============================
	;************************************************
	;	NGAN CACH GIUA CAC CHUONG TRINH
	;************************************************
;===============================
;SUBROUTINE TSEC
;	CHUONG TRINH TINH THOI GIAN
;INPUT: NONE
;OUTPUT: NONE
;===============================
TSECLUI:

	JNB	RUNF,NN
	SJMP	CHAY
NN:
	JNB	NNF,KHONG
CHAY:
	JB	STOP,KHONG
	INC	TIC
	MOV	A,TIC
	CJNE	A,#50,KTSEC1
	DEC	SEC
	MOV	TIC,#0
	MOV	A,SEC
	CJNE	A,#0FFH,KTSEC1
	MOV	SEC,#29
KHONG:
	MOV	P0,#0C0H
	SJMP	KTSEC1
KTSEC1:
	MOV	NUM,SEC
	RET
;===============================
;	KET THUC CHUONG TRINH
;===============================
	;************************************************
	;	NGAN CACH GIUA CAC CHUONG TRINH
	;************************************************
;===============================
;SUBROUTINE SLMODE
; CHUONG TRINH CHON MODE
;INPUT: NONE
;OUTPUT: NONE
;===============================
SLMODE:
	
	MOV	P1,#00
	JNB	PRUN,KTNN
	SETB	RUNF
	CLR	NNF
	CLR	STOP
	MOV	SEC,#0
	SJMP	KTSLMOD
KTNN:
	JNB	PNN,KTSTOP
	SETB	NNF
	CLR	RUNF
	CLR	STOP
	MOV	TIC,#0
	SJMP	KTSLMOD
KTSTOP:
	JNB	PSTOP,KTSLMOD
	CLR	RUNF
	CLR	NNF
	SETB	STOP
	MOV	P3,#0
KTSLMOD:
		
	RET

;===============================
;	KET THUC CHUONG TRINH
;===============================

	;************************************************
	;	NGAN CACH GIUA CAC CHUONG TRINH
	;************************************************
;===============================
;SUBROUTINE MODE1
; CHUONG TRINH CHAY CHE DO 1
;INPUT: NONE
;OUTPUT: NONE
;===============================
MODE1:
	JNB	RUNF,KTMODE1
	MOV	A,SEC
	CJNE	A,#29,SEC17
	MOV	P3,#21H
SEC17:
	CJNE	A,#17,SEC14
	MOV	P3,#22H
SEC14:
	CJNE	A,#14,SEC2
	MOV	P3,#0CH
SEC2:
	CJNE	A,#2,KTMODE1
	MOV	P3,#14H
KTMODE1:
	RET
;=================================
;	KET THUC CHUYEN TRINH CON
;=================================
	;************************************************
	;	NGAN CACH GIUA CAC CHUONG TRINH
	;************************************************
;===============================
;SUBROUTINE MODE2
; CHUONG TRINH CHAY CHE DO 2
;INPUT: NONE
;OUTPUT: NONE
;===============================
MODE2:
	JNB	NNF,KTMODE2
	JB	P1.0,LAM
	CPL	MODE2F
	MOV	A,MODE2F
	CJNE	A,#1,LAM
	MOV	P3,#0
	SJMP	KTMODE2
LAM:
	MOV	A,TIC
	CJNE	A,#0,V2
	MOV	P3,#12H
V2:
	CJNE	A,#26,KTMODE2
	MOV	P3,#0

KTMODE2:
	RET
;=================================
;	KET THUC CHUYEN TRINH CON
;=================================
	;************************************************
	;	NGAN CACH GIUA CAC CHUONG TRINH
	;************************************************
;===============================
;SUBROUTINE HEXTOBCD
;	HEX TO BCD
;INPUT: NUM
;OUTPUT: D1,D0
;===============================
HEXTOBCD:
	MOV	A,NUM	;CHUYEN "NUM" VAO THANH GHI "A"
	MOV	B,#10	;CHO THANH GHI "B" BANG 10
	DIV	AB	; CHIA LAY PHAN DU
	MOV	D0,B	;SO DU CHUYEN VAO B => CHUYEN PHAN DU VAO D0
	MOV	D1,A	;THUONG SO CHUYEN VAO A => CHUYEN THUONG SO VAO D1
	RET
;=================================
;	KET THUC CHUYEN TRINH CON
;=================================
	;************************************************
	;	NGAN CACH GIUA CAC CHUONG TRINH
	;************************************************
;==================================
;INT	INT_T2
; CHUONG TRINH HIEN THI SO LAN  AN PHIM VA HIEN THI
;INPUT: NONE
;OUTPUT: NONE
;===================================
INT_T2:
		
	CLR	TF2		;XOA CO BAO NGAT TRAN TIME2 "TF2"
	LCALL	HEXTOBCD	;GOI CHUONG TRINH "HEXTOBCD"
	LCALL	BCDTO7T		;GOI CHUONG TRINH "BCDTO7T"
	LCALL	DISPLAY
	LCALL	TSECLUI
	LCALL	SLMODE
	LCALL	MODE1
	LCALL	MODE2
KET:
	RETI
;===================================
;	KET THUC CHUONG TRINH
;===================================
	;************************************************
	;	NGAN CACH GIUA CAC CHUONG TRINH
	;************************************************
;===================================
;SUBROUTNI BCDTO7T
;INPUT: NONE
;OUTPUT: NONE
;===================================
BCDTO7T:
	MOV	DPTR,#SEGMENT	;CHUYEN MA 7 THANH VAO THANH GHI "DPTR"
	MOV	A,D0		;CHUYEN NOI DUNG D0 VAO THANH GHI "A"
	MOVC	A,@A+DPTR	;DOC NOI DUNG THANH GHI A CONG VOI NOI DUNG
				;THANH GHI "DPTR" KET QUA CAT "A"
	MOV	D0,A		;CHUYEN NOI DUNG D0 VAO THANH GHI "A"
	MOV	A,D1		;CHUYEN NOI DUNG D1 VAO THANH GHI "A"
	MOVC	A,@A+DPTR	;DOC NOI DUNG THANH GHI A CONG VOI NOI DUNG
				;THANH GHI "DPTR" KET QUA CAT "A"
	MOV	D1,A		;CHUYEN NOI DUNG D1 VAO THANH GHI "A"
	RET
;===================================
;	KET THUC CHUONG TRINH
;===================================
	;************************************************
	;	NGAN CACH GIUA CAC CHUONG TRINH
	;************************************************
;===================================
;SUBROUTINE DISPLAY
; HIEN THI LEN LED 7 THANH
;INPUT:
;OUTPUT:
;===================================
DISPLAY: 
	CJNE	R7,#0,LED2
	MOV	P2,#1B
	MOV	P0,D0
	
	SJMP	XLR7
LED2:	
	MOV	P2,#2
	MOV	P0,D1
XLR7:	
	INC	R7
	CJNE	R7,#2,KT	
	MOV	R7,#00H
KT:
	RET
	

;===================================
;	KET THUC CHUONG TRINH
;===================================
	;************************************************
	;	NGAN CACH GIUA CAC CHUONG TRINH
	;************************************************
;===================================
;	MA 7 THANH
;===================================
SEGMENT:	;THUOC BO NHO CHUONG TRINH "MOVC"
	DB	0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H
;SO THAP PHAN	 0    1     2    3   4   5   6   7    8  9
;====================================
;	KET THUC CHUONG TRINH
;====================================
          bạn có thể tham khảm chi tiết tại topic này http://www.dientuvietnam.net/forums/...ht=#post334573

          Comment

          • #6
            Nguyên văn bởi vippro1610 Xem bài viết
            @ haprohaui : Hix ko có code thi em sao tham khảo dc . Em xài 2 lần kiểm tra , lần 1 kiểm tra để chuyển từ ban ngày -> ban đêm , lần 2 thì từ ban đêm về lại ban ngày , em chỉ sử dụng 1 nút nhấn. Cái timer với counter hồi đó học lơ mơ quá nên ko dám xài . Em chỉ xài delay bình thường



            @tdm : Em vẫn ko biết chưa thoát CT con nào nữa . Cái mô phỏng của anh sao đèn xanh đỏ ko đèn nào sáng hết vậy

            ( Code này em edit lại cho nó gọn chứ vẫn giống như code em up ở trên )

            tg_xanh equ 50h
            tg_do equ 51h
            do equ 40
            xanh equ 35

            org 00h

            main:
            mov tg_xanh,#xanh
            mov tg_do,#do
            tudau:
            mov p1,#11110011b
            mov R0,tg_xanh
            mov R1,tg_do
            lap1: dec r0
            dec r1
            call hex_bcd
            call giaima
            call hienthi
            cjne r0,#0,lap1
            mov p1,#11110101b
            mov r0,#5
            lap2: dec r0
            dec r1
            call hex_bcd
            call giaima
            call hienthi
            cjne r0,#0,lap2
            mov p1,#11011110b
            mov r0,tg_do
            mov r1,tg_xanh
            lap3: dec r0
            dec r1
            call hex_bcd
            call giaima
            call hienthi
            cjne r1,#0,lap1
            mov p1,#11101110b
            mov r1,#5
            lap4: dec r0
            dec r1
            call hex_bcd
            call giaima
            call hienthi
            cjne r1,#0,lap4
            jmp tudau
            bandem:
            mov p1,#11101101b
            call delay500ms
            mov p1,#11111111b
            call delay500ms
            jmp bandem

            hex_bcd:
            mov A,R0
            mov B,#10
            div AB
            mov 37h,B
            mov 36h,A

            mov A,R1
            mov B,#10
            div AB
            mov 31h,B
            mov 30h,A
            Ret

            giaima:
            mov DPTR,#0500h
            mov A,37h
            movc A,@A+DPTR
            mov 27h,A
            mov A,36h
            movc A,@A+DPTR
            mov 26h,A
            mov A,31h
            movc A,@A+DPTR
            mov 21h,A
            mov A,30h
            movc A,@A+DPTR
            mov 20h,A
            Ret

            hienthi:
            mov R5,#150
            lap5:
            setb p2.0
            mov p0,26h
            call delay1ms
            clR p2.0
            setb p2.1
            mov p0,27h
            call delay1ms
            clR p2.1
            setb p2.2
            mov p0,20h
            call delay1ms
            clR p2.2
            setb p2.3
            mov p0,21h
            call delay1ms
            clR p2.3
            call kiemtra
            djnz R5,lap5
            ret

            kiemtra:
            jb p2.4,thoat ; kiem tra nut nhan de chuyen qua che do ban dem
            jnb p2.4,$ ; kiem tra nut nhan da dc nha
            jmp bandem
            thoat: ret

            delay1ms:
            mov 71h,#2
            D3: mov 72h,#255
            DJNZ 72h,$
            DJNZ 71h,D3
            Ret



            delay500ms:
            mov 73h,#2
            D6: mov 74h,#255
            D7: call kiemtra2
            mov 75h,#255
            DJNZ 75h,$
            DJNZ 74h,D7
            DJNZ 73h,D6
            Ret

            kiemtra2:
            jb p2.4,thoat1 ; kiem tra nut nhan de tro ve che do binh thuong
            jnb p2.4,$ ; kiem tra nut nhan da duoc nha
            jmp tudau
            thoat1: Ret

            org 0500h
            ma7d:
            DB 0c0h,0f9h,0a4h,0b0h,99h,92h,82h,0f8h,80h,90h

            end
            anh đã sửa lại cho em chạy OK:
            Code:
                tg_xanh    equ 50h
    tg_do    equ 51h
    do    equ 40
    xanh    equ 35     
    dem_ngay equ 52h
org 00h

main:
    mov dem_ngay,#0x00
    mov tg_xanh,#xanh
    mov tg_do,#do
tudau:
    mov p1,#11110011b  
    mov R0,tg_xanh
    mov R1,tg_do
lap1:    dec r0
    dec r1
    call hex_bcd
    call giaima
    call hienthi
    mov A, R0
    jz vang1
    cjne r0,#30,lap1
    mov p1,#10110011b
    jmp lap1

vang1:
    mov p1,#11110101b
    mov r0,#5
lap3:    dec r0
    dec r1
    call hex_bcd
    call giaima
    call hienthi
    cjne r0,#0,lap3
    jmp doitrangthai

doitrangthai:
    mov p1,#11011110b
    mov r0,tg_do
    mov r1,tg_xanh
lap2:    dec r0
    dec r1
    call hex_bcd
    call giaima
    call hienthi
    mov A,r1
    jz vang2
    cjne R1,#30,lap2
    mov p1,#01011110b
    jmp lap2

vang2:
    mov p1,#11101110b
    mov r1,#5
lap4:    dec r0
    dec r1
    call hex_bcd
    call giaima
    call hienthi
    cjne r1,#0,lap4
    jmp tudau

hex_bcd:
    mov A,R0
    mov B,#10
    div AB
    mov 37h,B
    mov 36h,A

    mov A,R1
    mov B,#10
    div AB
    mov 31h,B
    mov 30h,A
    Ret

giaima:
    mov DPTR,#0500h
    mov A,37h
    movc A,@A+DPTR
    mov 27h,A
    mov A,36h
    movc A,@A+DPTR
    mov 26h,A
    mov A,31h
    movc A,@A+DPTR
    mov 21h,A
    mov A,30h
    movc A,@A+DPTR
    mov 20h,A
    Ret

hienthi:
    mov R5,#150
lap5:
    setb p2.0
    mov p0,26h
    call delay1ms
    clR p2.0
    setb p2.1
    mov p0,27h
    call delay1ms
    clR p2.1
    setb p2.2
    mov p0,20h
    call delay1ms
    clR p2.2
    setb p2.3
    mov p0,21h
    call delay1ms
    clR p2.3
    call kiemtra
    djnz R5,lap5
thoat:
    ret
thoat_1:
    mov dem_ngay,#0x00
    mov R0,#xanh
    mov R1,#do
    mov p1,#11110011b 
      ret
kiemtra:
    jb p2.4,thoat    ;    kiem tra nut nhan de chuyen qua che do ban dem
    jnb p2.4,$    
    jmp bandem
    ret

delay1ms:
    mov 71h,#2
D3:    mov 72h,#255
    DJNZ 72h,$
    DJNZ 71h,D3
    Ret

bandem:    
    mov p1,#11101101b
    call delay500ms
    mov a, dem_ngay
    cjne a,#0xaa,tiep_1
    jmp thoat_1
tiep_1:
    mov p1,#11111111b
    call delay500ms
    mov a, dem_ngay
    cjne a,#0xaa,tiep_2
    jmp thoat_1
tiep_2:
    jmp bandem    

delay500ms:
    mov 73h,#2
D6:    mov 74h,#255
D7:    call kiemtra2
    mov a, dem_ngay
    cjne a,#0xaa,tiep
    jmp het
tiep:
    mov 75h,#255
    DJNZ 75h,$
    DJNZ 74h,D7
    DJNZ 73h,D6
het:
    Ret

kiemtra2:
    jb p2.4,thoat    ;     kiem tra nut nhan de tro ve che do binh thuong
    jnb p2.4,$    
    mov dem_ngay,#0xaa
    Ret

org 0500h
ma7d: 
DB 0c0h,0f9h,0a4h,0b0h,99h,92h,82h,0f8h,80h,90h

end
            Last edited by tdm; 22-04-2011, 23:24.
            |

            Comment

            Trước template Next

            Về tác giả

            Collapse
            vippro1610 Tìm hiểu thêm về vippro1610

            Bài viết mới nhất

            Collapse
            Xem toàn bộ
            Đang tải...
            X